XANSYS Message: 36415 [Go back to message list]
No rating yet
Subject: [input file]BCs mapping using *moper
Author: Sung-Chul Lee
Date: 2002-04-19 01:04:00Dear Users,
below is simple input file for testing *Moper command.
/prep7
et,1,45
mp,ex,1,200e9
mp,nuxy,1,0.3
block,,1,,1,,1
esize,0.5
vmesh,all
/SOLU
DA,2,ALL,
DA,1,UZ,-0.1
solve
/post1
/Edge,1,1
/view,1,1,1,1
plnsol,u,sum
/ui,copy,save,jpeg,,,,portrait
*get,ncount,node,,count
*dim,narray,array,ncount,1
*dim,inxyz,array,ncount,3
*dim,inval,array,ncount,3
narray(1,1)=ndnext(0)
*do,i,2,ncount
narray(i,1)=ndnext(narray(i-1,1))
*enddo
*do,i,1,ncount
inxyz(i,1)=nx(narray(i,1))
inxyz(i,2)=ny(narray(i,1))
inxyz(i,3)=nz(narray(i,1))
*enddo
*do,i,1,ncount
*get,inval(i,1),node,narray(i,1),u,x
*get,inval(i,2),node,narray(i,1),u,y
*get,inval(i,3),node,narray(i,1),u,z
*enddo
/prep7
vclear,all
esize,0.25
vmesh,all
*get,ncount2,node,,count
*dim,narray2,array,ncount2,1
*dim,resxyz,array,ncount2,3
*dim,resval,array,ncount2,3
narray2(1,1)=ndnext(0)
*do,i,2,ncount2
narray2(i,1)=ndnext(narray2(i-1,1))
*enddo
*do,i,1,ncount2
resxyz(i,1)=nx(narray2(i,1))
resxyz(i,2)=ny(narray2(i,1))
resxyz(i,3)=nz(narray2(i,1))
*enddo
*MOPER,ResVal(1,1),ResXYZ(1,1),MAP,InVal(1,1),InXYZ(1,1),3
/solu
DADELE,all,ALL
*do,i,1,ncount2
D,i,ux,resval(i,1)
D,i,uy,resval(i,2)
D,i,uz,resval(i,3)
*enddo
solve
/post1
/view,1,1,1,1
plnsol,u,sum
/ui,copy,save,jpeg,,,,portrait
Best regards.
Engineering Systems & Consulting Inc.
SUNG - CHUL LEE
Rm 701, Seokwang Bldg, 81-12, Shinchon-dong,
Dong-ku, Taeku, 701-023, Korea
Tel : 82-53-754-4597
Pcs : 016-462-0546
Fax : 82-53-754-4598
Email : golee26@n...
*^^* Let's smile,