XANSYS Message: 18516 [Go back to message list]
[bookmark on del.icio.us]
No rating yet
Rate item:

Subject: Re: Steady State to Transient Thermal
Author: Chris Soren
Date: 2000-11-30 14:19:00

JASON HUSBAND AND TED HARRIS,

> I am not convinced that your suggestion of turning on time
integration
> and restarting the steady state analysis will work. If you can do
this
> please post the deck.

HERE IS THE INPUT DECK. IT IS VM116 PROBLEM. IT DOES STEADY-STATE
SOLUTION AND RESTARTS THE SOLUTION WITH TIME INTEGRATION EFFECTS ON.
HENCE A USER DOES NOT NEED TO RERUN THE INITIAL STEADY-STATE ANALYSIS.

YOU SHOULD ASK YOUR ANSYS SUPPORT DISTRIBUTOR IF THIS STILL DOESN'T
CONVINCE YOU.

> I believe that Mr. Harris's strategy is sound and could be
> made to work. We regularly perform tricks such as this to map

I CAN ALSO PROVE THAT TED HARRIS'S SUGGESTION DOES NOT WORK.
STRUCTURAL THERMAL LOADS DO NOT EQUAL INITIAL TEMPERATURE D.O.F.
BOUNDARY CONDITIONS. I MODIFIED VM116 BELOW (SECOND INPUT DECK) TO
PROVE THIS AS WELL.

*******************SS TO TR RESTART*******************************

/PREP7
/TITLE, VM116, HEAT CONDUCTING PLATE WITH SUDDEN COOLING
C*** PRINCIPLES OF HEAT TRANSFER, KREITH, 2ND. PRINTING, PAGE 161,
EX. 4-11
ANTYPE,STATIC
ET,1,LINK34,,3 ! CONVECTION LINK, USE (TI-TJ) FOR HF EVALUATION
ET,2,LINK32 ! HEAT CONDUCTION BAR
R,1,1 ! UNIT AREA ASSUMED
MP,KXX,1,2 ! CONDUCTIVITY, DENSITY AND SPECIFIC HEAT
MP,DENS,1,800 ! INPUT USED BY CONDUCTION ELEMENTS
MP,C,1,0.833
MP,HF,1,2,.02 ! TEMPERATURE DEPENDENT HF (USED FOR ELEM 1)
N,1 ! NODES 1 AND 2 DEFINE THE CONVECTION LINK
N,2 ! (ARBIRARY LENGTH)
N,10,(8/12) ! CONDUCTION LENGTH IN FT.
FILL
E,1,2 ! ELEMENT 1 IS CONVECTION LINK
TYPE,2 ! ELEMENTS 2 THROUGH 9 ARE CONDUCTION BARS
E,2,3
EGEN,8,1,-1
FINISH
/SOLU
D,2,TEMP,500 ! INITIAL SURFACE TEMPERATURES
D,10,TEMP,100
OUTPR,,LAST
OUTRES,,ALL
TIME,0.001 ! INITIAL STEADY-STATE CONDITION
SOLVE
FINI
/POST1
SET,LAST
PLNS,TEMP
FINI
/SOLU
ANTYPE,STATIC,REST
TIMINT,ON ! TURN ON TIME INTEGRATION ON FOR
TIME,7 ! TRANSIENT OVER 7 HRS
DDELE,2,TEMP ! DELETE NODAL TEMPERATURE
D,1,TEMP,100 ! ENVIRONMENT TEMPERATURE IS DECREASED
KBC,1 ! SUDDENLY
AUTOTS,ON
NSUBST,20
SOLVE
FINISH

/POST26
NSOL,2,2,TEMP
PRVAR,2 ! PRINT TEMPERATURE HISTORY AT NODE 2
/AXLAB,Y,TEMP
/GRID,1
PLVAR,2
FINISH

/POST1
ETABLE,TI,SMISC,2 ! NODAL TEMPERATURES FOR CONDUCTION ELEMENTS
ETABLE,TJ,SMISC,3
PLLS,TI,TJ ! DISPLAY TEMPERATURE VARIATION ACROSS PLATE (AT 7
HRS)
PRNSOL,TEMP
*GET,TN2,NODE,2,TEMP
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'T,F(AT X'
LABEL(1,2) = '=0.0 in)'
*VFILL,VALUE(1,1),DATA,285
*VFILL,VALUE(1,2),DATA,TN2
*VFILL,VALUE(1,3),DATA,ABS(TN2/285)
/COM
/OUT,VM116,VRT
/COM,------------------- VM116 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.2)
/COM,-
/OUT
FINISH
*LIST,VM116,VRT

***************TED HARRIS SUGGESTION (DOESN'T WORK)*********

/PREP7
/TITLE, VM116, HEAT CONDUCTING PLATE WITH SUDDEN COOLING
C*** PRINCIPLES OF HEAT TRANSFER, KREITH, 2ND. PRINTING, PAGE 161,
EX. 4-11
ANTYPE,STATIC
ET,1,LINK34,,3 ! CONVECTION LINK, USE (TI-TJ) FOR HF EVALUATION
ET,2,LINK32 ! HEAT CONDUCTION BAR
R,1,1 ! UNIT AREA ASSUMED
MP,KXX,1,2 ! CONDUCTIVITY, DENSITY AND SPECIFIC HEAT
MP,DENS,1,800 ! INPUT USED BY CONDUCTION ELEMENTS
MP,C,1,0.833
MP,HF,1,2,.02 ! TEMPERATURE DEPENDENT HF (USED FOR ELEM 1)
N,1 ! NODES 1 AND 2 DEFINE THE CONVECTION LINK
N,2 ! (ARBIRARY LENGTH)
N,10,(8/12) ! CONDUCTION LENGTH IN FT.
FILL
E,1,2 ! ELEMENT 1 IS CONVECTION LINK
TYPE,2 ! ELEMENTS 2 THROUGH 9 ARE CONDUCTION BARS
E,2,3
EGEN,8,1,-1
FINISH
/SOLU
D,2,TEMP,500 ! INITIAL SURFACE TEMPERATURES
D,10,TEMP,100
OUTPR,,LAST
OUTRES,,ALL
TIME,0.001 ! INITIAL STEADY-STATE CONDITION
SOLVE
FINI
/POST1
SET,LAST
PLNS,TEMP
FINISH

/PREP7
ET,1,8
ET,2,8
FINI

/SOLU
LDREAD,TEMP,,, , ,,rth,
FINI

/PREP7
ET,1,LINK34,,3 ! CONVECTION LINK, USE (TI-TJ) FOR HF EVALUATION
ET,2,LINK32 ! HEAT CONDUCTION BAR
FINI

/SOLU
ANTYPE,TRANS
TIME,7 ! TRANSIENT OVER 7 HRS
DDELE,2,TEMP ! DELETE NODAL TEMPERATURE
D,1,TEMP,100 ! ENVIRONMENT TEMPERATURE IS DECREASED
KBC,1 ! SUDDENLY
AUTOTS,ON
NSUBST,20
SOLVE
FINISH

/POST26
NSOL,2,2,TEMP
PRVAR,2 ! PRINT TEMPERATURE HISTORY AT NODE 2
/AXLAB,Y,TEMP
/GRID,1
PLVAR,2
FINISH

/POST1
ETABLE,TI,SMISC,2 ! NODAL TEMPERATURES FOR CONDUCTION ELEMENTS
ETABLE,TJ,SMISC,3
PLLS,TI,TJ ! DISPLAY TEMPERATURE VARIATION ACROSS PLATE (AT 7
HRS)
PRNSOL,TEMP
*GET,TN2,NODE,2,TEMP
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'T,F(AT X'
LABEL(1,2) = '=0.0 in)'
*VFILL,VALUE(1,1),DATA,285
*VFILL,VALUE(1,2),DATA,TN2
*VFILL,VALUE(1,3),DATA,ABS(TN2/285)
/COM
/OUT,VM116,VRT
/COM,------------------- VM116 RESULTS COMPARISON -------------
/COM,
/COM, | TARGET | ANSYS | RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,' ',F10.0,' ',F10.0,' ',1F5.2)
/COM,-
/OUT
FINISH
*LIST,VM116,VRT

--- In xansys , Jason Husband wrote:
> Mr. Corbes
> I definately have performed transient analysis before so please
allow me
> to comment. I believe that Mr. Harris's strategy is sound and could
be
> made to work. We regularly perform tricks such as this to map
results
> sequentially back and forth between thermal and structural analyses.

> I believe the original problem of Mr. Singer was that he had
results
> from a static run and then wanted to continue with transient
analysis.
> For reasons unknown, he is reluctant to re-run this 1 step but is
> willing to run X number of steps in a transient (probably a few
percent
> increase in CPU time). Several Xansys members then offered possible
> solutions to help him.

> I am not convinced that your suggestion of turning on time
integration
> and restarting the steady state analysis will work. If you can do
this
> please post the deck.

> In general, for XANSYS as a whole, some of the suggestions are good
and
> some are not as good. Hopefully we can keep this group as a
discussion
> forum where people can offer solutions, good or not as good, and
not
> recieve a hostile reply.

> Best Regards
> Jason Husband
> QuEST

> Steve Cobes wrote:

> > TED HARRIS,

> > YOUR KIDDING RIGHT???!!!??? YOUR TELLING ME THAT STRUCTURAL
> > TEMPERATURE LOADING IS THE SAME AS THERMAL D.O.F.
SOLUTION???!!!???
> > THAT IS RIDICULOUS!!! YOU OBVIOUSLY HAVE NEVER DONE THERMAL
> > TRANSIENTS BEFORE.

> > EDMUND SINGER,

> > AS EVERYONE ELSE HAS RECOMMENDED, RESTART SOLUTION AS STEADY-
STATE
> > AND TURN ON TIME INTEGRATION EFFECTS. THIS DOES NOT REQUIRE RE-
> > SOLVING OF STEADY-STATE SOLUTION. DO NOT DO WHAT TED HARRIS
> > RECOMMENDS, SINCE IT IS OBVIOUSLY MORE STEPS AND IS WRONG.

> > --- In xansys , "Ted Harris" wrote:

> >> Edmund,
> >> There may be another way to do it, but I quickly tried using the
> >> LDREAD command to read the temperatures from the steady-state

> > analysis

> >> into the transient thermal analysis. I had to temporarily
change

> > the

> >> element type in /prep7 to a structural element, read in the
temps,

> > and

> >> then change back to a thermal element type. There may be a
better

> > way

> >> to do it, but hopefully this will work for you. Here is a
snippet

> > of my

> >> .log file:

> >> !steady-state run has been completed
> >> /SOLU
> >> !*
> >> ANTYPE,4
> >> !*
> >> TRNOPT,FULL
> >> LUMPM,0
> >> !*
> >> FINISH
> >> /prep7
> >> et,1,42
> >> FINISH
> >> /SOLU
> >> LDREAD,TEMP,,, , ,therm,rth,
> >> FINISH
> >> /prep7
> >> et,1,55
> >> FINISH
> >> /SOLU

> >> Ted Harris
> >> Phoenix Analysis & Design Technologies
> >> Gilbert, Arizona
> >> 480-813-4884
> >> 480-813-4807 fax
> >> www.padtinc.com
> >> www.anspak.com

> >>> -----Original Message-----
> >>> From: edmund_singer@u... [mailto:edmund_singer@u...]
> >>> Sent: Tuesday, November 28, 2000 11:48 AM
> >>> To: xansys
> >>> Subject: [xansys] Steady State to Transient Thermal

> >>> I am trying to run a transient analysis with starting

> > temperatures

> >>> that I have obtained from a previous Steady State analysis. I
am
> >>> unable to restart the analysis since the analysis type
changes.

> > Is

> >>> there a slick way to start with the steady state temperatures,

> > and

> >>> then run the transient, or must I store them in a table or

> > impress

> >>> them directly?

> >>> Thanks

> >>> Edmund Singer
> >>> Senior Engineer
> >>> Applied Mechanics
> >>> United Defense L.P.

Posts possibly associated with message #18516AuthorDateScore
18365Steady State to Transient ThermalEdmund Singer2000/11/28 
18367Re: Steady State to Transient ThermalJason Husband2000/11/28 
18368Re: Steady State to Transient ThermalTed Harris2000/11/28 
18369Re: Steady State to Transient ThermalEdmund Singer2000/11/28 
18372Re: Steady State to Transient ThermalNader Zamani2000/11/28 
18425Re: Steady State to Transient ThermalSteve Cobes stevecobes@2000/11/29 
18431Re: Steady State to Transient ThermalMadhusudan Pai2000/11/29 
18436Re: Steady State to Transient ThermalJason Husband2000/11/29 
18446Re: Steady State to Transient ThermalEdmund Singer2000/11/29 
18516Re: Steady State to Transient ThermalChris Soren2000/11/30 
18528Re: Steady State to Transient Thermal, worksCarlos Shultz2000/11/30 
18534Re: Steady State to Transient Thermal, workschankumar8@2000/11/30 
18571Re: Steady State to Transient Thermal, worksCarlos Shultz2000/12/01